Programming non-sense #2

Uno de mis hobbies es hacer que el ABAP haga cosas para las que no ha sido exactamente diseñando...asi que cuando aprendi a poner color a las celdas del ALV...siempre tuve la idea de hacer algo con eso...entonces, se me ocurrio hacer una especie de Paint.

En este caso, tenemos 4 colores disponibles, lo cuales se activan haciendo doble click en cada una de las celdas...si la celda esta en blanco y hacemos doble click...cambia de color, si volvemos a hacer doble click, cambia nuevamente...y asi hasta que regresa a blanco y continua.

Esta es la imagen para que se hagan una idea...


Y este el codigo fuente...espero que les guste -;)

REPORT zalv_painting NO STANDARD PAGE HEADING.

TYPE-POOLS: abap.
CLASS lcl_event_receiver DEFINITION DEFERRED.

DATA: it_fieldcatalog TYPE lvc_t_fcat,
      wa_fcat TYPE lvc_s_fcat,
      dataref TYPE REF TO data,
      new_line TYPE REF TO data,
      l_fieldname TYPE string,
      data_catalog TYPE REF TO data,
      t_stable TYPE STANDARD TABLE OF
      lvc_s_stbl WITH HEADER LINE,
      ct_fieldcat TYPE lvc_t_fcat,
      gs_layout TYPE lvc_s_layo,
      gs_variant TYPE disvariant,
      custom_container TYPE REF TO
      cl_gui_custom_container,
      it_color TYPE TABLE OF lvc_s_scol,
      it_color_aux TYPE TABLE OF lvc_s_scol,
      wa_color_aux TYPE lvc_s_scol,
      it_celltab TYPE lvc_t_styl,
      event_receiver TYPE REF TO lcl_event_receiver,
      grid1 TYPE REF TO cl_gui_alv_grid,
      mycontainer TYPE scrfname VALUE 'CUSTOM_ALV',
      ls_celltab TYPE lvc_s_styl,
      wa_color TYPE lvc_s_scol,
      l_color TYPE lvc_col,
      l_tabix(2) TYPE c,
      ok_code TYPE sy-ucomm,
      x_save.

FIELD-SYMBOLS: <row> TYPE table,
               <l_line> TYPE ANY,
               <l_field> TYPE ANY,
               <fs_catalog> TYPE lvc_s_fcat,
               <fs_color> LIKE LINE OF it_color,
               <fs_color_aux> LIKE LINE OF it_color_aux,
               <ct_fieldcat> LIKE LINE OF ct_fieldcat.

*-----------------------------------------------------*
* CLASS LCL_EVENT_RECEIVER DEFINITION                 *
*-----------------------------------------------------*
CLASS lcl_event_receiver DEFINITION.
  PUBLIC SECTION.
    METHODS: handle_double_click
             FOR EVENT double_click OF cl_gui_alv_grid
             IMPORTING e_row e_column.
ENDCLASS. "LCL_EVENT_RECEIVER DEFINITION

*-----------------------------------------------------*
* CLASS lcl_event_receiver IMPLEMENTATION             *
*-----------------------------------------------------*
CLASS lcl_event_receiver IMPLEMENTATION.
  METHOD handle_double_click.
    PERFORM paint_cell USING e_row e_column.
  ENDMETHOD.                    "handle_double_click
ENDCLASS. "LCL_EVENT_RECEIVER IMPLEMENTATION

*=====================================================*
* START-OF-SELECTION                                  *
*=====================================================*
START-OF-SELECTION.
  PERFORM create_structure.
  PERFORM fill_layout.
  PERFORM generate_alv_catalog.
  PERFORM call_alv.
  CALL SCREEN 0100.

*&----------------------------------------------------*
*&      Form  CREATE_STRUCTURE                        *
*&----------------------------------------------------*
FORM create_structure.

  DO 20 TIMES.
    l_tabix = l_tabix + 1.
    CONCATENATE 'FIELD' l_tabix INTO l_fieldname.
    wa_fcat-fieldname = l_fieldname.
    wa_fcat-ref_table = 'PERF_STRING_STRUCT'.
    wa_fcat-ref_field = 'DATA'.
    APPEND wa_fcat TO it_fieldcatalog.
  ENDDO.

  wa_fcat-fieldname     = 'COLOR'.
  wa_fcat-ref_table     = 'PERF_STRING_STRUCT'.
  wa_fcat-ref_field     = 'DATA'.
  APPEND wa_fcat TO it_fieldcatalog.

  wa_fcat-fieldname     = 'COLOR_CELL'.
  wa_fcat-ref_table     = 'RESC_DEFAULT_ALV_FIELDS'.
  wa_fcat-ref_field     = 'COLORTAB'.
  APPEND wa_fcat TO it_fieldcatalog.

  CALL METHOD cl_alv_table_create=>create_dynamic_table
    EXPORTING
      it_fieldcatalog           = it_fieldcatalog
    IMPORTING
      ep_table                  = dataref
    EXCEPTIONS
      generate_subpool_dir_full = 1
      OTHERS                    = 2.

  ASSIGN dataref->* TO <row>.
  CREATE DATA new_line LIKE LINE OF <row>.
  ASSIGN new_line->* TO <l_line>.

  DO 40 TIMES.
    INSERT <l_line> INTO TABLE <row>.
  ENDDO.

ENDFORM.                    " CREATE_STRUCTURE

*&----------------------------------------------------*
*&      Form  FILL_LAYOUT                             *
*&----------------------------------------------------*
FORM fill_layout.

  gs_layout-sel_mode = 'A'.
  gs_layout-ctab_fname = 'COLOR_CELL'.

ENDFORM.                    " FILL_LAYOUT

*&-----------------------------------------------------*
*&      Form  GENERATE_ALV_CATALOG                     *
*&-----------------------------------------------------*
FORM generate_alv_catalog.

  CREATE DATA data_catalog TYPE lvc_s_fcat.
  ASSIGN data_catalog->* TO <fs_catalog>.

  CLEAR l_tabix.

  DO 20 TIMES.
    l_tabix = l_tabix + 1.
    CONCATENATE 'FIELD' l_tabix INTO l_fieldname.
    APPEND INITIAL LINE TO ct_fieldcat
    ASSIGNING <ct_fieldcat>.
    <ct_fieldcat>-fieldname = l_fieldname.
  ENDDO.

ENDFORM.                    " GENERATE_ALV_CATALOG

*&------------------------------------------------------*
*&      Form  CALL_ALV                                  *
*&------------------------------------------------------*
FORM call_alv.

  IF custom_container IS INITIAL.
    CREATE OBJECT custom_container
      EXPORTING
        container_name              = mycontainer
      EXCEPTIONS
        cntl_error                  = 1
        cntl_system_error           = 2
        create_error                = 3
        lifetime_error              = 4
        lifetime_dynpro_dynpro_link = 5.
  ENDIF.

  CREATE OBJECT grid1
    EXPORTING
      i_parent = custom_container.

  CREATE OBJECT event_receiver.

  SET HANDLER event_receiver->handle_double_click FOR grid1.

  CALL METHOD grid1->set_table_for_first_display
    EXPORTING
      is_variant      = gs_variant
      i_save          = x_save
      i_default       = 'X'
      is_layout       = gs_layout
    CHANGING
      it_fieldcatalog = ct_fieldcat
      it_outtab       = <row>.

ENDFORM.                    " CALL_ALV

*&----------------------------------------------------*
*&      Module  STATUS_0100  OUTPUT                   *
*&----------------------------------------------------*
MODULE status_0100 OUTPUT.

  SET PF-STATUS '0100'.
  SET TITLEBAR 'TITLE'.

ENDMODULE.                 " STATUS_0100  OUTPUT

*&----------------------------------------------------*
*&      Module  USER_COMMAND_0100  INPUT              *
*&----------------------------------------------------*
MODULE user_command_0100 INPUT.

  ok_code = sy-ucomm.

  CASE ok_code.
    WHEN 'BACK' OR 'STOP' OR 'CANCEL'.
      SET SCREEN 0.
      LEAVE SCREEN.
  ENDCASE.

ENDMODULE.                 " USER_COMMAND_0100  INPUT

*&----------------------------------------------------*
*&      Form  PAINT_CELL                              *
*&----------------------------------------------------*
FORM paint_cell USING p_row
                      p_column.

  READ TABLE <row> ASSIGNING <l_line>
  INDEX p_row.
  IF sy-subrc EQ 0 AND <l_line> IS ASSIGNED.
    ASSIGN COMPONENT 22 OF STRUCTURE <l_line> TO <l_field>.
    it_color[] = <l_field>.
    READ TABLE it_color ASSIGNING <fs_color>
    WITH KEY fname = p_column.
    IF sy-subrc EQ 0 AND <fs_color> IS ASSIGNED.
      CASE <fs_color>-color-col.
        WHEN space or 2.
          l_color = 1.
        WHEN 1.
          l_color = 4.
        WHEN 4.
          l_color = 5.
        WHEN 5.
          l_color = 6.
        WHEN 6.
          l_color = 2. "White
      ENDCASE.

      MOVE l_color TO <fs_color>-color-col.
      MOVE p_column TO <fs_color>-fname.
    ELSE.
      l_color = 1.
      MOVE l_color TO wa_color-color-col.
      MOVE p_column TO wa_color-fname.
      APPEND wa_color TO it_color.
    ENDIF.

    ASSIGN COMPONENT 22 OF STRUCTURE <l_line> TO <l_field>.
    <l_field> = it_color[].

    CALL METHOD grid1->refresh_table_display
      EXPORTING
        is_stable = t_stable.
  ENDIF.

ENDFORM.                    " PAINT_CELL

Saludos,

Blag.

Programming non-sense #1

Con este post, quiero iniciar una pequeña serie de posts sobre programas en ABAP que no sirven para nada pero que son divertidos de hacer -:) Considero programar en ABAP divertido...aunque no lo crean...

En fin...mi primer código, que dicho sea de paso no funciona de la mejor manera, es un reloj...simplemente leemos la hora del sistema y la mostramos en forma digital...luego, activamos un temporizador que va a ejecutarse cada segundo y nuevamente va a leer la hora del sistema y mostrarla en formato digital...por supuesto, ya que no contamos en ABAP con un CLRSCR(); o un CLS, debemos leer cada linea y modificar el contenido.

DATA: temporizador TYPE REF TO cl_gui_timer,
      hour(2) TYPE c,
      minute(2) TYPE c,
      second(2) TYPE c,
      one(1) TYPE c,
      two(1) TYPE c,
      line1 TYPE string,
      line2 TYPE string,
      line3 TYPE string.

*----------------------------------------------------------------------*
*       CLASS clock DEFINITION                                         *
*----------------------------------------------------------------------*
CLASS clock DEFINITION.
  PUBLIC SECTION.
    METHODS: zero IMPORTING line TYPE string,
             one IMPORTING line TYPE string,
             two IMPORTING line TYPE string,
             three IMPORTING line TYPE string,
             four IMPORTING line TYPE string,
             five IMPORTING line TYPE string,
             six IMPORTING line TYPE string,
             seven IMPORTING line TYPE string,
             eight IMPORTING line TYPE string,
             nine IMPORTING line TYPE string,
             periods IMPORTING line TYPE string,
             show IMPORTING number TYPE c.
ENDCLASS.                    "clock DEFINITION

*----------------------------------------------------------------------*
*       CLASS clock IMPLEMENTATION                                     *
*----------------------------------------------------------------------*
CLASS clock IMPLEMENTATION.
  METHOD zero.
    CASE line.
      WHEN 1.
        CONCATENATE line1 ' _ ' INTO line1 SEPARATED BY space RESPECTING BLANKS.
      WHEN 2.
        CONCATENATE line2 '| |' INTO line2 SEPARATED BY space RESPECTING BLANKS.
      WHEN 3.
        CONCATENATE line3 '|_|' INTO line3 SEPARATED BY space RESPECTING BLANKS.
    ENDCASE.
  ENDMETHOD.                    "zero
  METHOD one.
    CASE line.
      WHEN 1.
        CONCATENATE line1 '  ' INTO line1 SEPARATED BY space RESPECTING BLANKS.
      WHEN 2.
        CONCATENATE line2 ' |' INTO line2 SEPARATED BY space RESPECTING BLANKS.
      WHEN 3.
        CONCATENATE line3 ' |' INTO line3 SEPARATED BY space RESPECTING BLANKS.
    ENDCASE.
  ENDMETHOD.                    "one
  METHOD two.
    CASE line.
      WHEN 1.
        CONCATENATE line1 ' _ ' INTO line1 SEPARATED BY space RESPECTING BLANKS.
      WHEN 2.
        CONCATENATE line2 ' _|' INTO line2 SEPARATED BY space RESPECTING BLANKS.
      WHEN 3.
        CONCATENATE line3 '|_ ' INTO line3 SEPARATED BY space RESPECTING BLANKS.
    ENDCASE.
  ENDMETHOD.                    "two
  METHOD three.
    CASE line.
      WHEN 1.
        CONCATENATE line1 ' _ ' INTO line1 SEPARATED BY space RESPECTING BLANKS.
      WHEN 2.
        CONCATENATE line2 ' _|' INTO line2 SEPARATED BY space RESPECTING BLANKS.
      WHEN 3.
        CONCATENATE line3 ' _|' INTO line3 SEPARATED BY space RESPECTING BLANKS.
    ENDCASE.
  ENDMETHOD.                    "three
  METHOD four.
    CASE line.
      WHEN 1.
        CONCATENATE line1 '   ' INTO line1 SEPARATED BY space RESPECTING BLANKS.
      WHEN 2.
        CONCATENATE line2 '|_|' INTO line2 SEPARATED BY space RESPECTING BLANKS.
      WHEN 3.
        CONCATENATE line3 '  |' INTO line3 SEPARATED BY space RESPECTING BLANKS.
    ENDCASE.
  ENDMETHOD.                    "four
  METHOD five.
    CASE line.
      WHEN 1.
        CONCATENATE line1 ' _ ' INTO line1 SEPARATED BY space RESPECTING BLANKS.
      WHEN 2.
        CONCATENATE line2 '|_ ' INTO line2 SEPARATED BY space RESPECTING BLANKS.
      WHEN 3.
        CONCATENATE line3 ' _|' INTO line3 SEPARATED BY space RESPECTING BLANKS.
    ENDCASE.
  ENDMETHOD.                    "five
  METHOD six.
    CASE line.
      WHEN 1.
        CONCATENATE line1 ' _ ' INTO line1 SEPARATED BY space RESPECTING BLANKS.
      WHEN 2.
        CONCATENATE line2 '|_ ' INTO line2 SEPARATED BY space RESPECTING BLANKS.
      WHEN 3.
        CONCATENATE line3 '|_|' INTO line3 SEPARATED BY space RESPECTING BLANKS.
    ENDCASE.
  ENDMETHOD.                    "six
  METHOD seven.
    CASE line.
      WHEN 1.
        CONCATENATE line1 '_  ' INTO line1 SEPARATED BY space RESPECTING BLANKS.
      WHEN 2.
        CONCATENATE line2 ' | ' INTO line2 SEPARATED BY space RESPECTING BLANKS.
      WHEN 3.
        CONCATENATE line3 ' | ' INTO line3 SEPARATED BY space RESPECTING BLANKS.
    ENDCASE.
  ENDMETHOD.                    "seven
  METHOD eight.
    CASE line.
      WHEN 1.
        CONCATENATE line1 ' _ ' INTO line1 SEPARATED BY space RESPECTING BLANKS.
      WHEN 2.
        CONCATENATE line2 '|_|' INTO line2 SEPARATED BY space RESPECTING BLANKS.
      WHEN 3.
        CONCATENATE line3 '|_|' INTO line3 SEPARATED BY space RESPECTING BLANKS.
    ENDCASE.
  ENDMETHOD.                    "eight
  METHOD nine.
    CASE line.
      WHEN 1.
        CONCATENATE line1 ' _ ' INTO line1 SEPARATED BY space RESPECTING BLANKS.
      WHEN 2.
        CONCATENATE line2 '|_|' INTO line2 SEPARATED BY space RESPECTING BLANKS.
      WHEN 3.
        CONCATENATE line3 ' _|' INTO line3 SEPARATED BY space RESPECTING BLANKS.
    ENDCASE.
  ENDMETHOD.                    "nine
  METHOD periods.
    CASE line.
      WHEN 1.
        CONCATENATE line1 '   ' INTO line1 SEPARATED BY space RESPECTING BLANKS.
      WHEN 2.
        CONCATENATE line2 ' * ' INTO line2 SEPARATED BY space RESPECTING BLANKS.
      WHEN 3.
        CONCATENATE line3 ' * ' INTO line3 SEPARATED BY space RESPECTING BLANKS.
    ENDCASE.
  ENDMETHOD.                    "periods
  METHOD show.
    CASE number.
      WHEN 0.
        zero( EXPORTING line = '1' ).
        zero( EXPORTING line = '2' ).
        zero( EXPORTING line = '3' ).
      WHEN 1.
        one( EXPORTING line = '1' ).
        one( EXPORTING line = '2' ).
        one( EXPORTING line = '3' ).
      WHEN 2.
        two( EXPORTING line = '1' ).
        two( EXPORTING line = '2' ).
        two( EXPORTING line = '3' ).
      WHEN 3.
        three( EXPORTING line = '1' ).
        three( EXPORTING line = '2' ).
        three( EXPORTING line = '3' ).
      WHEN 4.
        four( EXPORTING line = '1' ).
        four( EXPORTING line = '2' ).
        four( EXPORTING line = '3' ).
      WHEN   5.
        five( EXPORTING line = '1' ).
        five( EXPORTING line = '2' ).
        five( EXPORTING line = '3' ).
      WHEN 6.
        six( EXPORTING line = '1' ).
        six( EXPORTING line = '2' ).
        six( EXPORTING line = '3' ).
      WHEN 7.
        seven( EXPORTING line = '1' ).
        seven( EXPORTING line = '2' ).
        seven( EXPORTING line = '3' ).
      WHEN 8.
        eight( EXPORTING line = '1' ).
        eight( EXPORTING line = '2' ).
        eight( EXPORTING line = '3' ).
      WHEN 9.
        nine( EXPORTING line = '1' ).
        nine( EXPORTING line = '2' ).
        nine( EXPORTING line = '3' ).
    ENDCASE.
  ENDMETHOD.                    "show
ENDCLASS.                    "clock IMPLEMENTATION

*----------------------------------------------------------------------*
*       CLASS lcl_event_handler DEFINITION                             *
*----------------------------------------------------------------------*
CLASS lcl_event_handler DEFINITION.
  PUBLIC SECTION.
    CLASS-METHODS: on_timer FOR EVENT finished OF cl_gui_timer
    IMPORTING sender.
ENDCLASS.                    "lcl_event_handler DEFINITION

*----------------------------------------------------------------------*
*       CLASS lcl_event_handler IMPLEMENTATION                         * 
*----------------------------------------------------------------------*
CLASS lcl_event_handler IMPLEMENTATION.
  METHOD on_timer.
    DATA: g_clock TYPE REF TO clock.

    IF NOT g_clock IS BOUND.
      CREATE OBJECT g_clock.
    ENDIF.

    CLEAR: line1, line2, line3.

    hour = sy-uzeit+0(2).
    one = hour+0(1).
    g_clock->show( EXPORTING number = one ).
    two = hour+1(1).
    g_clock->show( EXPORTING number = two ).
    g_clock->periods( EXPORTING line = '1' ).
    g_clock->periods( EXPORTING line = '2' ).
    g_clock->periods( EXPORTING line = '3' ).
    minute = sy-uzeit+2(2).
    one = minute+0(1).
    g_clock->show( EXPORTING number = one ).
    two = minute+1(1).
    g_clock->show( EXPORTING number = two ).
    g_clock->periods( EXPORTING line = '1' ).
    g_clock->periods( EXPORTING line = '2' ).
    g_clock->periods( EXPORTING line = '3' ).
    second = sy-uzeit+4(2).
    one = second+0(1).
    g_clock->show( EXPORTING number = one ).
    two = second+1(1).
    g_clock->show( EXPORTING number = two ).

    READ LINE 1.
    MODIFY LINE 1 FIELD VALUE line1 FROM line1.
    READ LINE 2.
    MODIFY LINE 2 FIELD VALUE line2 FROM line2.
    READ LINE 3.
    MODIFY LINE 3 FIELD VALUE line3 FROM line3.

    sender->run( ).
  ENDMETHOD.
ENDCLASS.

START-OF-SELECTION.
  CREATE OBJECT temporizador.
  SET HANDLER lcl_event_handler=>on_timer FOR temporizador.

  temporizador->interval = 1.
  temporizador->run( ).

  DATA: g_clock TYPE REF TO clock.
  CREATE OBJECT g_clock.

  hour = sy-uzeit+0(2).
  one = hour+0(1).
  g_clock->show( EXPORTING number = one ).
  two = hour+1(1).
  g_clock->show( EXPORTING number = two ).
  g_clock->periods( EXPORTING line = '1' ).
  g_clock->periods( EXPORTING line = '2' ).
  g_clock->periods( EXPORTING line = '3' ).
  minute = sy-uzeit+2(2).
  one = minute+0(1).
  g_clock->show( EXPORTING number = one ).
  two = minute+1(1).
  g_clock->show( EXPORTING number = two ).
  g_clock->periods( EXPORTING line = '1' ).
  g_clock->periods( EXPORTING line = '2' ).
  g_clock->periods( EXPORTING line = '3' ).
  second = sy-uzeit+4(2).
  one = second+0(1).
  g_clock->show( EXPORTING number = one ).
  two = second+1(1).
  g_clock->show( EXPORTING number = two ).

  WRITE:/ line1.
  WRITE:/ line2.
  WRITE:/ line3.

Saludos,

Blag.